home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
mac
/
LOGIC Apple II 5.25" Library - ProDOS
/
PRO038A.dsk
/
RMAP.bas
< prev
next >
Wrap
BASIC Source File
|
2012-02-16
|
5KB
|
149 lines
100 REM RMAP
110 TEXT : HOME
120 POKE 49235,1: GR
130 POKE 48984,192: REM BITMAP
140 IF AUX < >1 THEN 230
150 IF MR = 1 THEN 210
160 PRINT D$;"SAVE /RAM/RMAP"
170 PRINT D$;"BLOAD MAP,A$400"
180 PRINT D$;"BSAVE/RAM/MAP,A$400,L$400"
190 MR = 1
200 GOTO 240
210 PRINT D$;"BLOAD /RAM/MAP,A$400"
220 GOTO 240
230 PRINT D$;"BLOAD MAP, A$400"
240 REM SHOW UNIT LOCATIONS
250 PRINT : PRINT
260 ON PL GOTO 510,940
270 F4 = 1: REM SHOW ELIM VEHICLES
280 FOR X1 = 1 TO 600
290 E = HX%(X1,1):F1 = X1:F = HX%(X1,0)
292 IF E <6 AND F = 0 THEN 380
300 GOSUB 990
302 IF PL = 1 AND ((F >99) AND F <199) THEN TU$ = "MINEFIELD": GOSUB 1220: COLOR= 0: PLOT F2,F3
304 IF PL = 2 AND (F >199) THEN TU$ = "MINEFIELD": GOSUB 1220: COLOR= 0: PLOT F2,F3
306 IF E <6 THEN 380
310 IF E <11 THEN GOSUB 1190: GOTO 370: REM TANK1
320 IF E <16 THEN GOSUB 1250: GOTO 370: REM APC1
330 IF E <21 THEN GOSUB 1310: GOTO 370: REM TANK2
340 IF E <26 THEN GOSUB 1370: GOTO 370: REM APC2
350 IF E <31 THEN GOSUB 1430: GOTO 370: REM SP1
360 IF E <36 THEN GOSUB 1490: GOTO 370: REM SP2
370 COLOR= 0: PLOT F2,F3
380 NEXT X1
390 REM RETURN TO PLATOON
400 PRINT : PRINT
410 PRINT "ENTER ANY NUMBER TO CONTINUE"
420 INPUT X
430 POKE 48984,207
440 PRINT D$;"FRE"
450 HOME
460 REM RETURN TO MAIN
470 GO = 7
480 POKE 103,1: POKE 104,24: POKE 6144,0
490 IF AUX THEN PRINT D$;"CHAIN /RAM/PLATOON."
500 PRINT D$;"CHAIN PLATOON."
510 REM PL#1 UNIT LOCATIONS
520 FOR F = 1 TO 10
530 IF PA(F,1) <.7 THEN GOTO 790
540 F1 = PA(F,4): REM HEX #
550 IF F1 <1 THEN GOTO 790
560 GOSUB 990: REM CALC X,Y FROM HEXNO
570 ON PL GOTO 590,580
580 ON PB(F,6) GOTO 600,630,660,690,720
590 ON PA(F,6) GOTO 600,630,660,690,720
600 F4 = 3: REM PURP,INF
610 TU$ = " INFANTRY"
620 GOTO 740
630 F4 = 2: REM DK.BLUE,ARM.
640 TU$ = " TANK"
650 GOTO 740
660 F4 = 9: REM ORANGE,APC
670 TU$ = " PERSONNEL CARRIER"
680 GOTO 740
690 F4 = 1: REM MAGENTA,HQ
700 TU$ = " LEADER"
710 GOTO 740
720 F4 = 13: REM YELLOW, SP
730 TU$ = " ARTILLERY"
740 PRINT
750 PRINT
760 PRINT
770 PRINT "LOCATION OF UNIT # ";F;TU$
780 GOSUB 810: REM SHOW LOCATION
790 NEXT F
800 GOTO 270: REM SHOW ELIM VEHICLES
810 FOR X = 1 TO 15: REM SUBR TO FLASH LOCATION
820 COLOR= F4
830 PLOT F2,F3
840 FOR TM = 1 TO 30: NEXT TM
850 COLOR= 0
860 PLOT F2,F3
870 FOR TM = 1 TO 30: NEXT TM
880 COLOR= F4
890 PLOT F2,F3
900 NEXT X
910 FOR TM = 1 TO 200: NEXT TM
920 RETURN
930 GOTO 390: REM TO READ MAP
940 REM PL#2 UNIT LOCATIONS
950 FOR F = 1 TO 10
960 IF PB(F,1) <.7 THEN GOTO 790
970 F1 = PB(F,4)
980 GOTO 550
990 IF F1 <31 THEN F2 = 10:F3 = F1: RETURN
1000 IF F1 <61 THEN F2 = 11:F3 = F1 -30: RETURN
1010 IF F1 <91 THEN F2 = 12:F3 = F1 -60: RETURN
1020 IF F1 <121 THEN F2 = 13:F3 = F1 -90: RETURN
1030 IF F1 <151 THEN F2 = 14:F3 = F1 -120: RETURN
1040 IF F1 <181 THEN F2 = 15:F3 = F1 -150: RETURN
1050 IF F1 <211 THEN F2 = 16:F3 = F1 -180: RETURN
1060 IF F1 <241 THEN F2 = 17:F3 = F1 -210: RETURN
1070 IF F1 <271 THEN F2 = 18:F3 = F1 -240: RETURN
1080 IF F1 <301 THEN F2 = 19:F3 = F1 -270: RETURN
1090 IF F1 <331 THEN F2 = 20:F3 = F1 -300: RETURN
1100 IF F1 <361 THEN F2 = 21:F3 = F1 -330: RETURN
1110 IF F1 <391 THEN F2 = 22:F3 = F1 -360: RETURN
1120 IF F1 <421 THEN F2 = 23:F3 = F1 -390: RETURN
1130 IF F1 <451 THEN F2 = 24:F3 = F1 -420: RETURN
1140 IF F1 <481 THEN F2 = 25:F3 = F1 -450: RETURN
1150 IF F1 <511 THEN F2 = 26:F3 = F1 -480: RETURN
1160 IF F1 <541 THEN F2 = 27:F3 = F1 -510: RETURN
1170 IF F1 <571 THEN F2 = 28:F3 = F1 -540: RETURN
1180 F2 = 29:F3 = F1 -570: RETURN
1190 REM TANK1
1200 IF PL = 1 THEN TU$ = "DESTROYED FRIENDLY TANK"
1210 IF PL = 2 THEN TU$ = "DESTROYED ENEMY TANK"
1220 PRINT : PRINT : PRINT
1230 PRINT TU$: GOSUB 810: REM SHOW LOCATION
1240 RETURN
1250 REM APC1
1260 IF PL = 1 THEN TU$ = "DESTROYED FRIENDLY CARRIER"
1270 IF PL = 2 THEN TU$ = "DESTROYED ENEMY CARRIER"
1280 PRINT : PRINT : PRINT
1290 PRINT TU$: GOSUB 810: REM SHOW LOCATION
1300 RETURN
1310 REM TANK2
1320 IF PL = 1 THEN TU$ = "DESTROYED ENEMY TANK"
1330 IF PL = 2 THEN TU$ = "DESTROYED FRIENDLY TANK"
1340 PRINT : PRINT : PRINT
1350 PRINT TU$: GOSUB 810: REM SHOW LOCATION
1360 RETURN
1370 REM APC2
1380 IF PL = 1 THEN TU$ = "DESTROYED ENEMY CARRIER"
1390 IF PL = 2 THEN TU$ = "DESTROYED FRIENDLY CARRIER"
1400 PRINT : PRINT : PRINT
1410 PRINT TU$: GOSUB 810: REM SHOW LOCATION
1420 RETURN
1430 REM SP1
1440 IF PL = 1 THEN TU$ = "DESTROYED FRIENDLY ARTILLERY"
1450 IF PL = 2 THEN TU$ = "DESTROYED ENEMY ARTILLERY"
1460 PRINT : PRINT : PRINT
1470 PRINT TU$: GOSUB 810: REM SHOW LOCATION
1480 RETURN
1490 REM SP2
1500 IF PL = 1 THEN TU$ = "DESTROYED ENEMY ARTILLERY"
1510 IF PL = 2 THEN TU$ = "DESTROYED FRIENDLY ARTILLERY"
1520 PRINT : PRINT : PRINT
1530 PRINT TU$: GOSUB 810: REM SHOW LOCATION
1540 RETURN